Riesz s - energy (s<d and s!=0, singular case)
Case d == 2 (0 < s < d )
Kernel expansion and remainder
In[827]:= d=2;
Sum[2^(-(s/2)) Pochhammer[s/2,m]/m! t^m,{m,0,\[Infinity]},Assumptions->{0 < s < d}]

Clear[d];
Out[828]= (2-2 t)^(-s/2)
In[830]:= d=2;
Sum[2^(-(s/2)) Pochhammer[s/2,m]/m! t^m,{m,M+1,\[Infinity]},Assumptions->{0 < s < d}]

Clear[d];
Out[831]= 1/(1+M)! 2^(-s/2) t^(1+M) Hypergeometric2F1[1,1+M+s/2,2+M,t] Pochhammer[s/2,1+M]
Linear transformation Abramowitz and Stegun, 15.3 .3
In[833]:= HHypergeometric2F1[1,1+M+s/2,2+M,t]/.ABR15x3xx3
Out[833]= (1-t)^(-s/2) HHypergeometric2F1[1+M,1-s/2,2+M,t]
2^(-s/2) Pochhammer[s/2,1+M]/(1+M)! t^(1+M) /(1-t)^(s/2) Hypergeometric2F1[1-s/2,1+M,2+M,t] ;
When following is positive, remainder (starting with even index term) can be resumed to a positive sum
In[1243]:= (Pochhammer[1-s/2,k]Pochhammer[1+M,k])/(Pochhammer[2+M,k]k!)//FunctionExpand
(%/.k->k+1)/(%/.k->k)//FullSimplify
Reduce[%<1&&0<s<2&&M>=1&&k>=0]
Out[1243]= ((1+M) Gamma[1+k-s/2])/((1+k+M) Gamma[1+k] Gamma[1-s/2])
Out[1244]= ((1+k+M) (2+2 k-s))/(2 (1+k) (2+k+M))
Out[1245]= 0<s<2&&M>=1&&k>=0
In[834]:= (Pochhammer[1-s/2,k]Pochhammer[1+M,k])/(Pochhammer[2+M,k]k!);
(%/.k->k)-(%/.k->k+1)//FunctionExpand//FullSimplify
Out[835]= ((1+M) (2+s+M s+k (2+s)) Gamma[1+k-s/2])/(2 (1+k+M) (2+k+M) Gamma[2+k] Gamma[1-s/2])
... positive for 0 < s < 2.
First resumation of leading terms (coefficient Subscript[A, d](M))
(1+(-1)^m)/2 2^(-(s/2)) Pochhammer[s/2,m]/m! Pochhammer[1/2,m/2]/Pochhammer[(d+1)/2,m/2]/.d->2//FullSimplify
Out[821]= (2^(-1-s/2) (1+(-1)^m) Gamma[m+s/2])/(Gamma[2+m] Gamma[s/2])
In[845]:= s=.;
TMP=Sum[(2^(-(s/2)) Gamma[2r+s/2])/(Gamma[2+2r] Gamma[s/2]),{r,0,(M-1)/2},Assumptions->{0<s<2}]//Distribute
Clear[s];
Out[846]= -(2^(1-s)/(-2+s))-(2^(-s/2) Gamma[1/2 (2+2 M+s)] HypergeometricPFQ[{1,1/2+M/2+s/4,1+M/2+s/4},{3/2+M/2,2+M/2},1])/(Gamma[3+M] Gamma[s/2])
In[848]:= TMP==2^(1-s)/(2-s)-(2^(-s/2) Gamma[1+M+s/2])/(Gamma[3+M] Gamma[s/2]) HypergeometricPFQ[{1,1/2+M/2+s/4,1+M/2+s/4},{3/2+M/2,2+M/2},1]//FullSimplify
Out[848]= True
In[1223]:= Wsd=2^(d-s-1) (Gamma[(d+1)/2]Gamma[(d-s)/2])/(Sqrt[\[Pi]]Gamma[d-s/2])/.d->2//FullSimplify
Out[1223]= -(2^(1-s)/(-2+s))
Application of Prudnikov etal III, 7.4 .4 .1
In[849]:= HHypergeometricPFQ[{1/2+M/2+s/4,1+M/2+s/4,1},{3/2+M/2,2+M/2},1]/.PBMx7x4x4xx1
During evaluation of In[849]:= 1-Re[s]/2>0, 1/2+Re[M]/2>0
Out[849]= (Gamma[3/2+M/2] Gamma[1-s/2] HHypergeometricPFQ[{3/2-s/4,1-s/4,1},{2-s/2,2+M/2},1])/(Gamma[1/2+M/2] Gamma[2-s/2])
Subscript[A, d][M]==2^(1-s)/(2-s)-(2^(-s/2) Gamma[1+M+s/2])/(Gamma[3+M] Gamma[s/2]) (1+M)/(2-s) HypergeometricPFQ[{3/2-s/4,1-s/4,1},{2-s/2,2+M/2},1];
In[1224]:= 2^(1-s)/(2-s)-(2^(-s/2) Gamma[1+M+s/2])/(Gamma[3+M] Gamma[s/2]) (1+M)/(2-s) Sum[(Pochhammer[3/2-s/4,ell]Pochhammer[1-s/4,ell])/(Pochhammer[2-s/2,ell]Pochhammer[2+M/2,ell]),{ell,0,10}];
Series[%,{M,\[Infinity],2}]
Out[1225]= 2^(1-s)/(2-s)+M^(1+s/2) (2^(-s/2)/((-2+s) Gamma[s/2] M^2)+O[1/M]^3)
In[862]:= Sum[2^(-(s/2)) Pochhammer[s/2,m]/m!,{m,0,M}]//FullSimplify//Distribute
Out[862]= (2^(-s/2) Gamma[1+M+s/2])/(Gamma[1+M] Gamma[1+s/2])
In[1247]:= 2^(1-s)/(2-s)-(2^(-s/2) Gamma[1+M+s/2])/(Gamma[3+M] Gamma[s/2]) (1+M)/(2-s) Sum[(Pochhammer[3/2-s/4,ell]Pochhammer[1-s/4,ell])/(Pochhammer[2-s/2,ell]Pochhammer[2+M/2,ell]),{ell,0,10}]-1/K (2^(-s/2) Gamma[1+M+s/2])/(Gamma[1+M] Gamma[1+s/2]);
Series[% K^2/.M->c K + \[Delta],{K,\[Infinity],1},Assumptions->{c>0,0<=\[Delta]<2}]//FullSimplify//Distribute
Out[1248]= (-((2^(1-s) K^2)/(-2+s))+O[1/K]^2)+K^(s/2) ((2^(-s/2) c^(-1+s/2) (-2 c (-2+s)+s) K)/((-2+s) s Gamma[s/2])-(2^(-3-s/2) c^(-2+s/2) (-1+2 c) (2+s+4 \[Delta]))/Gamma[s/2]+1/(3 Gamma[s/2] K) 2^(-7-s/2) c^(-3+s/2) ((-4+s) (3 s^2+48 \[Delta] (1+\[Delta])+2 s (5+12 \[Delta]))-2 c (-2+s) (8+3 s^2+48 \[Delta] (1+\[Delta])+2 s (5+12 \[Delta])))+O[1/K]^(3/2))
2^(1-s)/(2-s) K^2+((2^(-s/2) (c^(-1+s/2)) (-4 c-s+2 c s) )/((2-s) s Gamma[s/2]))K^(1+s/2);
In[1275]:= F=(2^(-1-s/2) (c^(-1+s/2)) (-4 c-s+2 c s) )/((2-s) Gamma[1+s/2]);

Plot3D[F,{c,0,2},{s,0,2},AxesLabel->Automatic]

Fp=D[F,c]//FullSimplify

sol=Solve[Fp==0,c]//Flatten

F/.sol//FullSimplify
Out[1276]= 
Out[1277]= (2^(-1-s/2) (1-2 c) c^(-2+s/2))/Gamma[s/2]
Out[1278]= {c->1/2}
Out[1279]= 2^(1-s)/((-2+s) Gamma[1+s/2])
Out[895]= True
2^(1-s)/(2-s) K^2-(2^(1-s)/((2-s)  Gamma[1+s/2]))K^(1+s/2)
In[1426]:= d=2; (* hexagonal lattice *)

covolume=Sqrt[3]/2;
ZetaA2=6Zeta[s]3^-s (Zeta[s,1/3]-Zeta[s,2/3]);

\[Omega]d=(2\[Pi]^((d+1)/2))/Gamma[(d+1)/2];
Wsd=2^(d-s-1) (Gamma[(d+1)/2]Gamma[(d-s)/2])/(Sqrt[\[Pi]]Gamma[d-s/2]);
Csd=covolume^(s/d) (ZetaA2/.s->s/2);

Print["conjectured"];
boundconj=Csd/\[Omega]d^(s/d)//FunctionExpand//FullSimplify
N[%,24];

(* Series[Wsd,{s,d,1}]//FullSimplify

Series[Csd/\[Omega]d^(s/d),{s,d,1}]//FullSimplify*)

Print["known bound"];
Cd=1/d Gamma[(d+1)/2]/(Sqrt[\[Pi]]Gamma[d/2]);
ctilde=-((2^(-(s/2)) s^(-(s/2)))/(1-s/2));
N[ctilde,24];

Print["new bound"];
boundnew=-(2^(1-s)/((2-s)  Gamma[1+s/2]));
N[cstar[d,d],24];

plot=Plot[{boundconj,boundnew,ctilde},{s,0,2},PlotStyle->{Dashed,Automatic,Dotted},WorkingPrecision->128]

Print["comparision (absolute and relative)"];

plotA=Plot[{Abs[(boundconj-boundnew)/boundconj],boundconj-boundnew},{s,0,2},WorkingPrecision->128,PlotStyle->{Dashed,Automatic,Dotted},GridLines->{None,{0.025}},PlotRange->{All,{0,0.025}}]

plotB=Plot[{Abs[(boundconj-ctilde)/boundconj],boundconj-ctilde},{s,0,2},WorkingPrecision->128,PlotStyle->{Dashed,Automatic,Dotted},GridLines->{None,{0.35}},PlotRange->{All,{0,0.35}}]



(* Plot[{boundconj,boundnew},{s,0,2},WorkingPrecision\[Rule]64,Epilog\[Rule]Inset[plotA,{-3,0.1},{.5,0},1]]*)



Clear[\[Omega]d,Wsd,Csd,d,Cd];
During evaluation of In[1426]:= conjectured
Out[1433]= 2^(1-(3 s)/2) 3^(1-s/4) \[Pi]^(-s/2) Zeta[s/2] (Zeta[s/2,1/3]-Zeta[s/2,2/3])
During evaluation of In[1426]:= known bound
During evaluation of In[1426]:= new bound
Out[1442]= 
During evaluation of In[1426]:= comparision (absolute and relative)
Out[1444]= 
Out[1445]= 
Riesz d - energy (boundary case)
In[1]:= AdM[2,M_]:=1/4 (PolyGamma[0,1+M/2]+EulerGamma+2Log[2]);
AdM[4,M_]:=3/8 (PolyGamma[0,2+M/2]+EulerGamma+2Log[2]-2);
AdM[8,M_]:=35/64 (PolyGamma[0,4+M/2]+EulerGamma+2 Log[2]-11/3+3/(6+M));
AdM[24,M_]:=2028117 /2097152 (PolyGamma[0,12+M/2]+EulerGamma+2 Log[2]-83711/13860+693/(128 (14+M))-7161/(64 (16+M))+9471/(16 (18+M))-71511/(64 (20+M))+87923/(128 (22+M)));
d == 2 (hexagonal lattice)
In[456]:= d=2;

Cd=1/d Gamma[(d+1)/2]/(Sqrt[\[Pi]]Gamma[d/2]) (* leading term constant *)

Series[(AdM[d,M]-2^(-d/2)  Pochhammer[1+d/2,M]/M! 1/K)K^2/.M->(c K)^(2/d)+\[Delta],{K,\[Infinity],-1},Assumptions->{c>0,0<=\[Delta]<2}]//FullSimplify[#,Assumptions->{c>0,0<=\[Delta]<2}]&

Clear[d];
Out[457]= 1/4
Out[458]= 1/4 (-2 c+EulerGamma+Log[2 c K]) K^2-(((-1+2 c) (1+\[Delta])) K)/(4 c)+O[1/K]^0
Leading terms of asymptotics
In[460]:= TMP =1/4 (-2 c+EulerGamma+Log[2 c K]) K^2-(((-1+2 c) (1+\[Delta])) K)/(4 c);
TMP==1/4 K^2 Log[K]+1/4 (EulerGamma+Log[2]+Log[c]-2c) K^2-((-1+2 c) (1+\[Delta])) /(4 c) K//FullSimplify[#,Assumptions->{c>0,K>0}]&
Out[461]= True
In[462]:= d=2;

1/4==Cd
1/4==d/2 Cd

Clear[d];
Out[463]= True
Out[464]= True
Optimizing function of N^2-term
In[466]:= F=1/4 (EulerGamma+Log[2]+Log[c]-2c);

Plot[F,{c,0,2}]

Fp=D[F,c]//FullSimplify

sol=Solve[Fp==0,c]//Flatten

F/.sol//FullSimplify

N[%,24]
Out[467]= 
Out[468]= 1/4 (-2+1/c)
Out[469]= {c->1/2}
Out[470]= 1/4 (-1+EulerGamma)
Out[471]= -0.105696083774616784848372
In[5]:= cstar[2,2](* cstar[s_,d_] *)=1/4 (EulerGamma-1);

N[cstar[2,2],24]

Out[6]= -0.105696083774616784848372
In[474]:= -(((-1+2 c) (1+\[Delta])) /(4 c))K/.sol//FullSimplify
Out[474]= 0
0;
Comparison with known bound and conjecture
In[529]:= d=2; (* hexagonal lattice *)

covolume=Sqrt[3]/2;
ZetaA2=6Zeta[s]3^-s (Zeta[s,1/3]-Zeta[s,2/3])

\[Omega]d=(2\[Pi]^((d+1)/2))/Gamma[(d+1)/2];
Wsd=2^(d-s-1) (Gamma[(d+1)/2]Gamma[(d-s)/2])/(Sqrt[\[Pi]]Gamma[d-s/2]);
Csd=covolume^(s/d) (ZetaA2/.s->s/2);

Print["conjectured"];
boundconj=Limit[Wsd+Csd/\[Omega]d^(s/d),s->d]//FunctionExpand//FullSimplify
N[%,24]

(* Series[Wsd,{s,d,1}]//FullSimplify

Series[Csd/\[Omega]d^(s/d),{s,d,1}]//FullSimplify*)

Print["known bound"];
Cd=1/d Gamma[(d+1)/2]/(Sqrt[\[Pi]]Gamma[d/2]);
ctilde=-Cd(1-Log[Cd]+d(PolyGamma[d/2]+EulerGamma-Log[2]))//FullSimplify
N[ctilde,24]

Print["new bound"];
N[cstar[d,d],24]

Print["comparision (absolute and relative)"];

N[boundconj-cstar[d,d],24]

N[Abs[(boundconj-cstar[d,d])/cstar[d,d] 100],24]

Clear[\[Omega]d,Wsd,Csd,d,Cd];
Out[530]= 2 3^(1-s) Zeta[s] (Zeta[s,1/3]-Zeta[s,2/3])
During evaluation of In[529]:= conjectured
Out[535]= 1/(8 \[Pi])(2 EulerGamma \[Pi]-\[Pi] Log[12 \[Pi]^2]+2 Sqrt[3] (-StieltjesGamma[1,1/3]+StieltjesGamma[1,2/3]))
Out[536]= -0.0857684103009024836558217
During evaluation of In[529]:= known bound
Out[539]= -(1/4)
Out[540]= -0.250000000000000000000000
During evaluation of In[529]:= new bound
Out[542]= -0.105696083774616784848372
During evaluation of In[529]:= comparision (absolute and relative)
Out[544]= 0.0199276734737143011925503
Out[545]= 18.8537481825792950125183
In[7]:= Cconj[2,2](* Cconj[s_,d_] *)=1/4 (EulerGamma-Log[2Sqrt[3] \[Pi]])+Sqrt[3]/(4\[Pi]) (StieltjesGamma[1,2/3]-StieltjesGamma[1,1/3]);

N[Cconj[2,2],24]

Out[8]= -0.0857684103009024836558217
d == 4 (checkerboard lattice)
In[399]:= d=4;

Cd=1/d Gamma[(d+1)/2]/(Sqrt[\[Pi]]Gamma[d/2]) (* leading term constant *)

Series[(AdM[d,M]-2^(-d/2)  Pochhammer[1+d/2,M]/M! 1/K)K^2/.M->(c K)^(2/d)+\[Delta],{K,\[Infinity],-1},Assumptions->{c>0,0<=\[Delta]<2}]//FullSimplify[#,Assumptions->{c>0,0<=\[Delta]<2}]&

Clear[d];
Out[400]= 3/16
Out[401]= 1/16 (-2 (6+c-3 EulerGamma)+3 Log[4 c K]) K^2+((9-3 c+3 \[Delta]-2 c \[Delta]) K^(3/2))/(8 Sqrt[c])+1/O[1/K]
Leading terms of asymptotics
In[409]:= TMP =1/16 (-2 (6+c-3 EulerGamma)+3 Log[4 c K]) K^2+((9-3 c+3 \[Delta]-2 c \[Delta]) K^(3/2))/(8 Sqrt[c]);
TMP==3/16 K^2 Log[K]+3/8 (EulerGamma+Log[2]-2+Log[c]/2-c/3) K^2+(9-3 c-(-3+2 c) \[Delta] )/(8 Sqrt[c])  K^(3/2)//FullSimplify[#,Assumptions->{c>0,K>0}]&
Out[410]= True
In[411]:= d=4;

3/16==Cd
3/8==d/2 Cd

Clear[d];
Out[412]= True
Out[413]= True
Optimizing function of N^2-term
In[415]:= F=3/8 (EulerGamma+Log[2]-2+Log[c]/2-c/3);

Plot[F,{c,0,2}]

Fp=D[F,c]//FullSimplify

sol=Solve[Fp==0,c]//Flatten

F/.sol//FullSimplify

N[%,24]
Out[416]= 
Out[417]= -(1/8)+3/(16 c)
Out[418]= {c->3/2}
Out[419]= 3/16 (-5+2 EulerGamma+Log[6])
Out[420]= -0.385089225181664864620218
In[9]:= cstar[4,4](* cstar[s_,d_] *)=3/8 (EulerGamma+1/2 Log[2]+1/2 Log[3]-5/2);

N[cstar[4,4],24]

Out[10]= -0.385089225181664864620218
In[427]:= (9-3 c-(-3+2 c) \[Delta] )/(8 Sqrt[c])  K^(3/2)/.sol//FullSimplify
Out[427]= 3/8 Sqrt[3/2] K^(3/2)
3/8 Sqrt[3/2] K^(3/2);
Comparison with known bound and conjecture
In[428]:= d=4; (* checkerboard lattice *)

covolume=1;
ZetaD4=24 2^(-(s/2)) (1-2^(1-s))Zeta[s]Zeta[s-1]//FullSimplify//FunctionExpand

\[Omega]d=(2\[Pi]^((d+1)/2))/Gamma[(d+1)/2];
Wsd=2^(d-s-1) (Gamma[(d+1)/2]Gamma[(d-s)/2])/(Sqrt[\[Pi]]Gamma[d-s/2]);
Csd=covolume^(s/d) (ZetaD4/.s->s/2);

Print["conjectured"];
boundconj=Limit[Wsd+Csd/\[Omega]d^(s/d),s->d]
N[%,24]

(* Series[Wsd,{s,d,1}]//FullSimplify

Series[Csd/\[Omega]d^(s/d),{s,d,1}]//FullSimplify*)

Print["known bound"];
Cd=1/d Gamma[(d+1)/2]/(Sqrt[\[Pi]]Gamma[d/2]);
ctilde=-Cd(1-Log[Cd]+d(PolyGamma[d/2]+EulerGamma-Log[2]))//FullSimplify
N[ctilde,24]

Print["new bound"];
N[cstar[d,d],24]

Print["comparision (absolute and relative)"];

N[boundconj-cstar[d,d],24]

N[Abs[(boundconj-cstar[d,d])/cstar[d,d] 100],24]

Clear[\[Omega]d,Wsd,Csd,d,Cd];
Out[429]= 3 2^(3-(3 s)/2) (-2+2^s) Zeta[-1+s] Zeta[s]
During evaluation of In[428]:= conjectured
Out[434]= 3/16 (-2+2 EulerGamma+Log[12]-2 Log[\[Pi]]+(12 (Zeta^\[Prime])[2])/\[Pi]^2)
Out[435]= -0.335633208430649986808222
During evaluation of In[428]:= known bound
Out[438]= 3/16 (-5+Log[3])
Out[439]= -0.731510195874729432863392
During evaluation of In[428]:= new bound
Out[441]= -0.385089225181664864620218
During evaluation of In[428]:= comparision (absolute and relative)
Out[443]= 0.0494560167510148778119966
Out[444]= 12.8427422833459252019925
In[11]:= Cconj[4,4](* Cconj[s_,d_] *)=3/8 (-1+EulerGamma+Log[2]+1/2 Log[3]+(6 (Zeta^\[Prime])[2])/\[Pi]^2-Log[\[Pi]]);

N[Cconj[4,4],24]

Out[12]= -0.335633208430649986808222
d == 8 (Subscript[E, 8] lattice)
In[322]:= d=8;

Cd=1/d Gamma[(d+1)/2]/(Sqrt[\[Pi]]Gamma[d/2]) (* leading term constant *)

Series[(AdM[d,M]-2^(-d/2)  Pochhammer[1+d/2,M]/M! 1/K)K^2/.M->(c K)^(2/d)+\[Delta],{K,\[Infinity],-1},Assumptions->{c>0,0<=\[Delta]<2}]//FullSimplify[#,Assumptions->{c>0,0<=\[Delta]<2}]&

Clear[d];
Out[323]= 35/256
Out[324]= 1/768 (-2 c+35 (-44+12 EulerGamma+Log[4096]+3 Log[c K])) K^2+((105 (10+\[Delta])-c (5+2 \[Delta])) K^(7/4))/(192 c^(1/4))+((-c (35+6 \[Delta] (5+\[Delta]))-35 (254+3 \[Delta] (20+\[Delta]))) K^(3/2))/(384 Sqrt[c])+1/(192 c^(3/4))(-c (5+2 \[Delta]) (5+\[Delta] (5+\[Delta]))+35 (6+\[Delta]) (110+\[Delta] (24+\[Delta]))) K^(5/4)+1/O[1/K]
Leading terms of asymptotics
In[338]:= TMP = 1/768 (-2 c+35 (-44+12 EulerGamma+Log[4096]+3 Log[c K])) K^2+((105 (10+\[Delta])-c (5+2 \[Delta])) K^(7/4))/(192 c^(1/4));
TMP==35/256 K^2 Log[K]+35/64 (EulerGamma+Log[2]-11/3+1/4 Log[c]-c/210) K^2+(1050-5 c-(-105+2 c) \[Delta])/(192 c^(1/4))  K^(7/4)//FullSimplify[#,Assumptions->{c>0,K>0}]&
Out[339]= True
In[340]:= d=8;

35/256==Cd
35/64==d/2 Cd

Clear[d];
Out[341]= True
Out[342]= True
Optimizing function of N^2-term
In[350]:= F=35/64 (EulerGamma+Log[2]-11/3+1/4 Log[c]-c/210);

Plot[F,{c,0,100}]

Fp=D[F,c]//FullSimplify

sol=Solve[Fp==0,c]//Flatten

F/.sol//FullSimplify

N[%,24]
Out[351]= 
Out[352]= 1/768 (-2+105/c)
Out[353]= {c->105/2}
Out[354]= 35/768 (-47+12 EulerGamma+Log[592704000])
Out[355]= -0.905679976690668583480722
In[13]:= cstar[8,8](* cstar[s_,d_] *)=35/64 (EulerGamma+3/4 Log[2]+1/4 Log[3]+1/4 Log[5]+1/4 Log[7]-47/12);

N[cstar[8,8],24]

Out[14]= -0.905679976690668583480722
In[367]:= (1050-5 c-(-105+2 c) \[Delta])/(192 c^(1/4))  K^(7/4)/.sol//FullSimplify
Out[367]= 5/64 (105/2)^(3/4) K^(7/4)
5/64 (105/2)^(3/4) K^(7/4);
Comparison with known bound and conjecture
In[368]:= d=8; (* E8 lattice *)

covolume=1;
ZetaE8=240 2^-s Zeta[s]Zeta[s-3]//FullSimplify//FunctionExpand


\[Omega]d=(2\[Pi]^((d+1)/2))/Gamma[(d+1)/2];
Wsd=2^(d-s-1) (Gamma[(d+1)/2]Gamma[(d-s)/2])/(Sqrt[\[Pi]]Gamma[d-s/2]);
Csd=covolume^(s/d) (ZetaE8/.s->s/2);

Print["conjectured"];
boundconj=Limit[Wsd+Csd/\[Omega]d^(s/d),s->d]
N[%,24]

(* Series[Wsd,{s,d,1}]//FullSimplify

Series[Csd/\[Omega]d^(s/d),{s,d,1}]//FullSimplify*)

Print["known bound"];
Cd=1/d Gamma[(d+1)/2]/(Sqrt[\[Pi]]Gamma[d/2]);
ctilde=-Cd(1-Log[Cd]+d(PolyGamma[d/2]+EulerGamma-Log[2]))//FullSimplify
N[ctilde,24]

Print["new bound"];
N[cstar[d,d],24]

Print["comparision (absolute and relative)"];

N[boundconj-cstar[d,d],24]

N[Abs[(boundconj-cstar[d,d])/cstar[d,d] 100],24]

Clear[\[Omega]d,Wsd,Csd,d,Cd];
Out[369]= 15 2^(4-s) Zeta[-3+s] Zeta[s]
During evaluation of In[368]:= conjectured
Out[374]= 35/768 (-22+12 EulerGamma+Log[1157625/8]-12 Log[\[Pi]]+(1080 (Zeta^\[Prime])[4])/\[Pi]^4)
Out[375]= -0.806265483426581312938899
During evaluation of In[368]:= known bound
Out[378]= 35/768 (-47+Log[42875])
Out[379]= -1.65584434055157755681101
During evaluation of In[368]:= new bound
Out[381]= -0.905679976690668583480722
During evaluation of In[368]:= comparision (absolute and relative)
Out[383]= 0.0994144932640872705418224
Out[384]= 10.9767794168692213232203
In[15]:= Cconj[8,8](* Cconj[s_,d_] *)=35/64 (-(11/6)+EulerGamma-1/4 Log[2]+1/4 Log[3]+1/4 Log[5]+1/4 Log[7]+90 /\[Pi]^4 (Zeta^\[Prime])[4]-Log[\[Pi]]);

N[Cconj[8,8],24]

Out[16]= -0.806265483426581312938899
d == 24 (Leech lattice)
In[185]:= d=24;

Cd=1/d Gamma[(d+1)/2]/(Sqrt[\[Pi]]Gamma[d/2]) (* leading term constant *)

Series[(AdM[d,M]-2^(-d/2)  Pochhammer[1+d/2,M]/M! 1/K)K^2/.M->(c K)^(2/d)+\[Delta],{K,\[Infinity],-1},Assumptions->{c>0,0<=\[Delta]<2}]//FullSimplify[#,Assumptions->{c>0,0<=\[Delta]<2}]&

Clear[d];
Out[186]= 676039/8388608
Out[187]= ((-2 c+273795795 (-83711+13860 EulerGamma+13860 Log[2]+1155 Log[c K])) K^2)/3923981107200+((316234143225 (78+\[Delta])-c (13+2 \[Delta])) K^(23/12))/(326998425600 c^(1/12))+((-c (247+6 \[Delta] (13+\[Delta]))-28748558475 (11816+3 \[Delta] (156+\[Delta]))) K^(11/6))/(178362777600 c^(1/6))+((-c (13+2 \[Delta]) (39+\[Delta] (13+\[Delta]))+5749711695 (161304+\[Delta] (11816+\[Delta] (234+\[Delta])))) K^(7/4))/(17836277760 c^(1/4))+1/(118908518400 c^(1/3)) (-2 c (22711+15 \[Delta] (13+\[Delta]) (78+\[Delta] (13+\[Delta])))-1916570565 (87218827+15 \[Delta] (645216+\[Delta] (23632+\[Delta] (312+\[Delta]))))) K^(5/3)+1/(29727129600 c^(5/12)) (-c (13+2 \[Delta]) (8073+2 \[Delta] (13+\[Delta]) (221+3 \[Delta] (13+\[Delta])))+1916570565 (576391530+\[Delta] (87218827+\[Delta] (4839120+\[Delta] (118160+3 \[Delta] (390+\[Delta])))))) K^(19/12)+1/(178362777600 Sqrt[c]) (-c (4090021+42 \[Delta] (13+\[Delta]) (8073+\[Delta] (13+\[Delta]) (221+2 \[Delta] (13+\[Delta]))))-28748558475 (5958023874+\[Delta] (1152783060+\[Delta] (87218827+\[Delta] (3226080+\[Delta] (59080+\[Delta] (468+\[Delta]))))))) K^(3/2)+1/(29727129600 c^(7/12)) (-c (13+2 \[Delta]) (240175+\[Delta] (13+\[Delta]) (21359+6 \[Delta] (13+\[Delta]) (104+\[Delta] (13+\[Delta]))))+1368978975 (528068888580+\[Delta] (125118501354+\[Delta] (12104222130+\[Delta] (610531789+3 \[Delta] (5645640+\[Delta] (82712+\[Delta] (546+\[Delta])))))))) K^(17/12)+1/(713451110400 c^(2/3)) (-4 c (59746076+15 \[Delta] (13+\[Delta]) (480350+\[Delta] (13+\[Delta]) (21359+\[Delta] (13+\[Delta]) (416+3 \[Delta] (13+\[Delta])))))-28748558475 (15016779285216+\[Delta] (4224551108640+\[Delta] (500474005416+\[Delta] (32277925680+\[Delta] (1221063578+\[Delta] (27099072+\[Delta] (330848+3 \[Delta] (624+\[Delta]))))))))) K^(4/3)+1/(89181388800 c^(3/4)) (-c (13+2 \[Delta]) (4944108+\[Delta] (13+\[Delta]) (648544+\[Delta] (13+\[Delta]) (31122+5 \[Delta] (13+\[Delta]) (130+\[Delta] (13+\[Delta])))))+1916570565 (690116991031296+\[Delta] (225251689278240+\[Delta] (31684133314800+\[Delta] (2502370027080+\[Delta] (121042221300+\[Delta] (3663190734+5 \[Delta] (13549536+\[Delta] (141792+\[Delta] (702+\[Delta])))))))))) K^(5/4)+1/(653996851200 c^(5/6)) (-c (643853184+11 \[Delta] (13+\[Delta]) (9888216+\[Delta] (13+\[Delta]) (648544+\[Delta] (13+\[Delta]) (20748+\[Delta] (13+\[Delta]) (325+2 \[Delta] (13+\[Delta]))))))-63246828645 (3710490529278304+\[Delta] (1380233982062592+\[Delta] (225251689278240+\[Delta] (21122755543200+\[Delta] (1251185013540+\[Delta] (48416888520+\[Delta] (1221063578+\[Delta] (19356480+\[Delta] (177240+\[Delta] (780+\[Delta]))))))))))) K^(7/6)+1/(980995276800 c^(11/12)) (-c (13+2 \[Delta]) (57170880+\[Delta] (13+\[Delta]) (10752768+\[Delta] (13+\[Delta]) (774540+\[Delta] (13+\[Delta]) (26936+\[Delta] (13+\[Delta]) (455+3 \[Delta] (13+\[Delta]))))))+28748558475 (292970958029253312+\[Delta] (122446187466184032+\[Delta] (22773860704032768+\[Delta] (2477768582060640+\[Delta] (174262733231400+\[Delta] (8257821089364+\[Delta] (266292886860+\[Delta] (5756442582+\[Delta] (79845480+\[Delta] (649880+3 \[Delta] (858+\[Delta])))))))))))) K^(13/12)+1/O[1/K]
Leading terms of asymptotics
In[159]:= TMP = ((-2 c+273795795 (-83711+13860 EulerGamma+13860 Log[2]+1155 Log[c K])) K^2)/3923981107200+((316234143225 (78+\[Delta])-c (13+2 \[Delta])) K^(23/12))/(326998425600 c^(1/12));
TMP==676039/8388608 K^2 Log[K]+2028117/2097152 (EulerGamma+Log[2]+Log[c]/12-c/1897404859350-83711/13860) K^2+(24666263171550-13 c-(-316234143225+2 c) \[Delta])/(326998425600 c^(1/12)) K^(23/12)//FullSimplify[#,Assumptions->{c>0,K>0}]&
Out[160]= True
In[189]:= d=24;

676039/8388608==Cd
2028117/2097152==d/2 Cd

Clear[d];
Out[190]= True
Out[191]= True
Optimizing function of N^2-term
In[167]:= F=2028117/2097152 (EulerGamma+Log[2]+Log[c]/12-c/1897404859350-83711/13860);

Plot[F,{c,0,316234143225}]

Fp=D[F,c]//FullSimplify

sol=Solve[Fp==0,c]//Flatten

F/.sol//FullSimplify

N[%,24]
Out[168]= 
Out[169]= -(1/1961990553600)+676039/(8388608 c)
Out[170]= {c->316234143225/2}
Out[171]= 1/20971522028117 (-(42433/6930)+EulerGamma+Log[2]+1/12 Log[316234143225/2])
In[17]:= cstar[24,24](* cstar[s_,d_] *)=2028117 /2097152 (EulerGamma+11/12 Log[2]+5/12 Log[3]+1/6 Log[5]+1/6 Log[7]+1/12 Log[11]+1/12 Log[13]+1/12 Log[17]+1/12 Log[19]+1/12 Log[23]-42433/6930);

N[cstar[24,24],24]

Out[18]= -2.61483542770544488035975
In[183]:= (24666263171550-13 c-(-316234143225+2 c) \[Delta])/(326998425600 c^(1/12)) K^(23/12)/.sol//FullSimplify
Out[183]= (13 3^(7/12) 7^(5/6) 1062347^(11/12) K^(23/12))/(2097152 2^(11/12) 5^(1/6))
(13 (3^(7/12)) (7^(5/6)) (1062347^(11/12)) )/(2097152 2^(11/12) 5^(1/6)) K^(23/12);
Comparison with known bound and conjecture
In[288]:= d=24; (* Leech *)

covolume=1;
Zeta\[CapitalLambda]24=65520/691 2^-s (Zeta[s]Zeta[s-11]-RamanujanTauL[s])//FullSimplify//FunctionExpand


\[Omega]d=(2\[Pi]^((d+1)/2))/Gamma[(d+1)/2];
Wsd=2^(d-s-1) (Gamma[(d+1)/2]Gamma[(d-s)/2])/(Sqrt[\[Pi]]Gamma[d-s/2]);
Csd=covolume^(s/d) (Zeta\[CapitalLambda]24/.s->s/2);

Print["conjectured"];
boundconj=Limit[Wsd+Csd/\[Omega]d^(s/d),s->d]
N[%,24]

(* Series[Wsd,{s,d,1}]//FullSimplify

Series[Csd/\[Omega]d^(s/d),{s,d,1}]//FullSimplify*)

Print["known bound"];
Cd=1/d Gamma[(d+1)/2]/(Sqrt[\[Pi]]Gamma[d/2]);
ctilde=-Cd(1-Log[Cd]+d(PolyGamma[d/2]+EulerGamma-Log[2]))//FullSimplify
N[ctilde,24]

Print["new bound"];
N[cstar[24,24],24]

Print["comparision (absolute and relative)"];

N[boundconj-cstar[24,24],24]

N[Abs[(boundconj-cstar[24,24])/cstar[24,24] 100],24]

Clear[\[Omega]d,Wsd,Csd,d,Cd];
Out[289]= -(4095/691) 2^(4-s) (RamanujanTauL[s]-Zeta[-11+s] Zeta[s])
During evaluation of In[288]:= conjectured
Out[294]= 1/(1912854282240 \[Pi]^12) 96577 (691 \[Pi]^12 (-83711+27720 EulerGamma-2310 Log[2]+11550 Log[3]+2310 Log[13]+4620 Log[35]+2310 Log[81719]-27720 Log[\[Pi]])-17699576895000 (RamanujanTauL[12]-(Zeta^\[Prime])[12]))
Out[295]= -2.35288856549984884934600
During evaluation of In[288]:= known bound
Out[298]= (96577 (-84866+27720 Log[2]-1155 Log[8388608/676039]))/1384120320
Out[299]= -4.78382223827582489254442
During evaluation of In[288]:= new bound
Out[301]= -2.61483542770544488035975
During evaluation of In[288]:= comparision (absolute and relative)
Out[303]= 0.261946862205596031013749
Out[304]= 10.0177188755415522400067
In[19]:= Cconj[24,24](* Cconj[s_,d_] *)=2028117/2097152 (EulerGamma-Log[2]/12+(5 Log[3])/12+Log[5]/6+Log[7]/6+Log[11]/12+Log[13]/12+Log[17]/12+Log[19]/12+Log[23]/12-83711/27720+638512875 /(691 \[Pi]^12) (Zeta^\[Prime])[12]-638512875 /(691 \[Pi]^12) RamanujanTauL[12]-Log[\[Pi]]);

N[Cconj[24,24],24]

Out[20]= -2.35288856549984884934600
Proof of CBHS--C22 relation
Numerics
CBHS=2Log[2]+1/2 Log[2/3]+3Log[Sqrt[\[Pi]]/Gamma[1/3]];

C22=1/4 (EulerGamma-Log[2Sqrt[3]\[Pi]])+Sqrt[3]/(4\[Pi]) (StieltjesGamma[1,2/3]-StieltjesGamma[1,1/3]);

CBHS-2C22==Log[2]-EulerGamma//FullSimplify

Block[{$MaxExtraPrecision=1000},N[CBHS-2C22-(Log[2]-EulerGamma),256]]
Out[4]= 12 \[Pi] Log[Gamma[1/3]]==2 EulerGamma \[Pi]+\[Pi] Log[(256 \[Pi]^8)/3]+2 Sqrt[3] (StieltjesGamma[1,1/3]-StieltjesGamma[1,2/3])
During evaluation of In[1]:= N::meprec: Internal precision limit $MaxExtraPrecision = 1000.` reached while evaluating EulerGamma-1/2 Log[3/2]+Log[2]+3 Log[Sqrt[\[Pi]]/(<<5>><<1>><<1>>])]-2 (1/4 (EulerGamma-Log[Times[<<3>>]])+(Sqrt[3] (-<<1>>+<<14>>[1,<<1>>]))/(4 \[Pi])).
Out[5]= 0.*10^-1255
Malmsten' s identity
m=1;
n=3;

REF=StieltjesGamma[1,m/n]-StieltjesGamma[1,1-m/n]
RES=2\[Pi] Sum[Sin[(2\[Pi] m ell)/n]Log[Gamma[ell/n]],{ell,1,n-1}]-\[Pi] (EulerGamma+Log[2\[Pi] n])Cot[(\[Pi] m)/n]

N[REF-RES,32]

Block[{$MaxExtraPrecision=1000},N[REF-RES,16]]

Clear[m,n];
Out[37]= StieltjesGamma[1,1/3]-StieltjesGamma[1,2/3]
Out[38]= -((\[Pi] (EulerGamma+Log[6 \[Pi]]))/Sqrt[3])+2 \[Pi] (1/2 Sqrt[3] Log[Gamma[1/3]]-1/2 Sqrt[3] Log[Gamma[2/3]])
During evaluation of In[35]:= N::meprec: Internal precision limit $MaxExtraPrecision = 50.` reached while evaluating (\[Pi] (EulerGamma+Log[6 \[Pi]]))/Sqrt[3]-2 \[Pi] (1/2 Sqrt[3] Log[Gamma[1/3]]-1/2 Sqrt[3] Log[Gamma[2/3]])+<<1>>-StieltjesGamma[1,2/3].
Out[39]= 0.*10^-81
During evaluation of In[35]:= N::meprec: Internal precision limit $MaxExtraPrecision = 1000.` reached while evaluating (\[Pi] (EulerGamma+Log[6 \[Pi]]))/Sqrt[3]-2 \[Pi] (1/2 Sqrt[3] Log[Gamma[1/3]]-1/2 Sqrt[3] Log[Gamma[2/3]])+<<1>>-StieltjesGamma[1,2/3].
Out[40]= 0.*10^-1015
In[74]:= m=2;
n=3;

REF=StieltjesGamma[1,m/n]-StieltjesGamma[1,1-m/n]
RES=2\[Pi] Sum[Sin[(2\[Pi] m ell)/n]Log[Gamma[ell/n]],{ell,1,n-1}]-\[Pi] (EulerGamma+Log[2\[Pi] n])Cot[(\[Pi] m)/n]

CBHS=2Log[2]+1/2 Log[2/3]+3Log[Sqrt[\[Pi]]/Gamma[1/3]];

C22=1/4 (EulerGamma-Log[2Sqrt[3]\[Pi]])+Sqrt[3]/(4\[Pi]) (RES (* StieltjesGamma[1,2/3]-StieltjesGamma[1,1/3] *) );


CBHS-2C22//Simplify

CBHS-2C22==Log[2]-EulerGamma//FullSimplify


Clear[m,n];
Out[76]= -StieltjesGamma[1,1/3]+StieltjesGamma[1,2/3]
Out[77]= (\[Pi] (EulerGamma+Log[6 \[Pi]]))/Sqrt[3]+2 \[Pi] (-(1/2) Sqrt[3] Log[Gamma[1/3]]+1/2 Sqrt[3] Log[Gamma[2/3]])
Out[80]= 1/4 (-4 EulerGamma+Log[1024/27]+6 Log[\[Pi]/(Gamma[1/3] Gamma[2/3])])
Out[81]= True
In[83]:= 1/4 (-4 EulerGamma+Log[1024/27]+6 Log[\[Pi]/(Gamma[1/3] Gamma[2/3])])//FullSimplify
Out[83]= -EulerGamma+Log[2]
In[84]:= Gamma[1/3] Gamma[2/3]//FullSimplify
Out[84]= (2 \[Pi])/Sqrt[3]
In[88]:= 1/4 (-4 EulerGamma+Log[1024/27]+6 Log[\[Pi]/(Gamma[1/3] Gamma[2/3])]);
%==1/4 (-4 EulerGamma+10Log[2]-3Log[3]+6 Log[\[Pi]/(Gamma[1/3] Gamma[2/3])])
Out[89]= True